Automatic Sliding Door PID System Control

1. Libraries, Pin Definitions & PID Constants

This section includes the required headers for I2C communication (Wire.h), servo motor control (Servo.h), and the Adafruit VL53L0X laser ranging library. Pins are assigned for the ultrasonic sensor trigger/echo and servo PWM lines. The optimal tuned control constants (\(K_p = 0.8\), \(K_i = 0.015\), \(K_d = 0.6\)) are declared globally.

#include <Wire.h>
#include <Servo.h>
#include <Adafruit_VL53L0X.h>

#define TRIG_PIN 4
#define ECHO_PIN 5
#define SERVO_PIN 9

Servo slidingDoorServo;
Adafruit_VL53L0X lox = Adafruit_VL53L0X();
bool isOpen = 0;
VL53L0X_RangingMeasurementData_t measure;

// Tuned optimal PID Constants
float kp = 0.8;
float ki = 0.015;
float kd = 0.6;

2. System Initialization (setup)

The setup() routine initializes the 9600 baud serial port for tracking logs, defines digital I/O modes for the HC-SR04 pins, initializes the VL53L0X sensor over the I2C bus, and attaches the servo motor. The door is commanded to the default closed state (rotary servo angle mapped to 142°).

void setup() {
  Serial.begin(9600);
  pinMode(TRIG_PIN, OUTPUT);
  pinMode(ECHO_PIN, INPUT);

  if (!lox.begin()) {
    Serial.println("Failed to initialize VL53L0X!");
    while (1);
  }
  slidingDoorServo.attach(SERVO_PIN);
  slidingDoorServo.write(142); // Default closed position (angle mapped)
}

3. Laser Ranging Feedback (doorPos)

This function performs a real-time distance measurement using the Time-of-Flight (ToF) laser sensor. It queries the sensor, checks if the ranging status flag is valid (filtering out-of-range sensor dropouts), and returns the raw distance in millimeters.

int doorPos() {
  lox.rangingTest(&measure, false);
  if (measure.RangeStatus != 4) {
    return measure.RangeMilliMeter;
  } else return -1;
}

4. Closed-Loop PID Control Loop

The core PIDControl() routine implements the discrete-time PID algorithm. It runs inside a while loop that active-monitors the distance error until the door settles inside a ±3 mm deadband around the target setpoint. It computes error, accumulates integral error, takes derivative error changes, and adds the feedforward setpoint term to offset steady-state gravity/friction. The resulting output in millimeters is scaled and constrained to fit the servo's physical range (23° to 160°).

void PIDControl(int setpoint, float* previousError, float* integral) {
  int currentPosition = doorPos();

  while(setpoint < currentPosition - 3 || setpoint > currentPosition + 3) {
    if (currentPosition == -1) return;

    float error = setpoint - currentPosition;
    *integral += error;
    float derivative = error - (*previousError);

    // Compute output position in mm
    float output = (kp * error + (ki * (*integral)) + (kd * derivative)) + setpoint;
    *previousError = error;

    // Map mm output back to rotary servo degrees and constrain
    int servoInput = constrain(output * 142 / 274, 23, 160);
    slidingDoorServo.write(servoInput);

    currentPosition = doorPos();
    delay(50); // Control loop interval
  }
}

5. Opening & Closing Handlers

These wrapper functions trigger the control routine with target setpoints: 52 mm for opening and 269 mm for closing. They initialize the local error tracking variables to zero, ensuring each step response begins with clean initial conditions.

void PIDopen() {
  float prevErr = 0, integ = 0;
  PIDControl(52, &prevErr, &integ);
  delay(250);
}

void PIDclose() {
  float prevErr = 0, integ = 0;
  PIDControl(269, &prevErr, &integ);
  delay(250);
}

6. Sonar Distance Reading (getDistance)

This helper reads the HC-SR04 ultrasonic sensor. It sends a short high pulse (10 microseconds) to trigger the sonar transmitter, reads the duration of the return echo via pulseIn(), and converts the time delay into distance in millimeters based on the speed of sound.

int getDistance() {
  digitalWrite(TRIG_PIN, LOW);
  delayMicroseconds(2);
  digitalWrite(TRIG_PIN, HIGH);
  delayMicroseconds(10);
  digitalWrite(TRIG_PIN, LOW);
  int duration = pulseIn(ECHO_PIN, HIGH);
  int distance = duration * 0.344 / 2;
  return distance;
}

7. Main Program Loop (loop)

The primary executive loop runs every 100ms. It checks the ultrasonic sensor's distance reading. If a person is detected within the 115 mm proximity range, it initiates the PIDopen() transition. Otherwise, if the door is open and no one is in proximity, it initiates PIDclose().

void loop() {  
  if(getDistance() < 115) { // Ultrasonic threshold trigger
    if(!isOpen) PIDopen(), isOpen = 1;
  } else {
    if(isOpen) PIDclose(), isOpen = 0;
  }
  delay(100);
}

Live Demonstration Video